summaryrefslogtreecommitdiff
path: root/macho64/acopy.s
blob: cde434c9fb667098e46abbbc99af1ebe4cf738a3 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
1017
1018
1019
1020
1021
1022
1023
1024
1025
1026
1027
1028
1029
1030
1031
1032
1033
1034
1035
1036
1037
1038
1039
1040
1041
1042
1043
1044
1045
1046
1047
1048
1049
1050
1051
1052
1053
1054
1055
1056
1057
1058
1059
1060
1061
1062
1063
1064
1065
1066
1067
1068
1069
1070
1071
1072
1073
1074
1075
1076
1077
1078
1079
1080
1081
1082
1083
1084
1085
1086
1087
1088
1089
1090
1091
1092
1093
1094
1095
1096
1097
1098
1099
1100
1101
1102
1103
1104
1105
1106
1107
1108
1109
1110
1111
1112
1113
1114
1115
1116
1117
1118
1119
1120
1121
1122
1123
1124
1125
1126
1127
1128
1129
1130
1131
1132
1133
1134
1135
1136
1137
1138
1139
1140
1141
1142
1143
1144
1145
1146
1147
1148
1149
1150
1151
1152
1153
1154
1155
1156
1157
1158
1159
1160
1161
1162
1163
1164
1165
1166
1167
1168
1169
1170
1171
1172
1173
1174
1175
1176
1177
1178
1179
1180
1181
1182
1183
1184
1185
1186
1187
1188
1189
1190
1191
1192
1193
1194
1195
1196
1197
1198
1199
1200
1201
1202
1203
1204
1205
1206
1207
1208
1209
1210
1211
1212
1213
1214
1215
1216
1217
1218
1219
1220
1221
1222
1223
1224
1225
1226
1227
1228
1229
1230
1231
1232
1233
1234
1235
1236
1237
1238
1239
1240
1241
1242
1243
1244
1245
1246
1247
1248
1249
1250
1251
1252
1253
1254
1255
1256
1257
1258
1259
1260
1261
1262
1263
1264
1265
1266
COPY_RECORDS_WITHOUT_POINTERS_TO_END_OF_HEAP = 1

	push	rsi

	mov	rdi,[rip+heap_p2]

	mov	rax,[rip+heap_size_257]
	shl	rax,7
	mov	[rip+semi_space_size],rax 
	lea	rsi,[rdi+rax]

	mov	qword ptr [rip+heap2_begin_and_end+8],rsi 

	mov	rax,qword ptr [rip+caf_list]
	test	rax,rax 
	je	end_copy_cafs

copy_cafs_lp:
	push	[rax-8]
	
	lea	rbp,[rax+8]
	mov	rbx,qword ptr [rax]
	sub	rbx,1
	call	copy_lp2
	
	pop	rax
	test	rax,rax
	att_jne	copy_cafs_lp

end_copy_cafs:
	mov	rbx,qword ptr [rsp]
	mov	rbp,[rip+stack_p]
	sub	rbx,rbp
	shr	rbx,3

	sub	rbx,1
	jb	end_copy0
	att_call	copy_lp2
end_copy0:
	mov	rbp,[rip+heap_p2]

	jmp	copy_lp1
/* */
/*	Copy all referenced nodes to the other semi space */
/* */

in_hnf_1_2:
	dec	rbx
copy_lp2_lp1:
	att_call	copy_lp2
copy_lp1:
	cmp	rbp,rdi
	jae	end_copy1

	mov	rax,[rbp]
	add	rbp,8
	test	al,2
	je	not_in_hnf_1
in_hnf_1:
	movzx	rbx,word ptr [rax-2]

	test	rbx,rbx
	je	copy_array_21

	cmp	rbx,2
	att_jbe	in_hnf_1_2

	cmp	rbx,256
	jae	copy_record_21
	
	mov	rax,[rbp+8]

	test	al,1
	jne	node_without_arguments_part

	push	rbx
	xor	rbx,rbx 
	
	att_call	copy_lp2

	pop	rbx 
	add	rbp,8

	sub	rbx,2
	att_jmp	copy_lp2_lp1

node_without_arguments_part:
	dec	rax 
	xor	rbx,rbx 

	mov	[rbp+8],rax 
	att_call	copy_lp2
	
	add	rbp,8
	att_jmp	copy_lp1

copy_record_21:
	sub	rbx,258
	ja	copy_record_arguments_3

	movzx	rbx,word ptr [rax-2+2]
 .if COPY_RECORDS_WITHOUT_POINTERS_TO_END_OF_HEAP
	att_jb	in_hnf_1_2

	sub	rbx,1
	att_ja	copy_lp2_lp1
	jmp	copy_node_arity1
 .else
	jb	copy_record_arguments_1

	sub	rbx,1
	ja	copy_lp2_lp1
	je	copy_node_arity1
	add	rbp,16
	jmp	copy_lp1

copy_record_arguments_1:
	dec	rbx
	jmp	copy_lp2_lp1
	je	copy_lp2_lp1
	add	rbp,8
	jmp	copy_lp1
 .endif

copy_record_arguments_3:
	test	byte ptr [rbp+8],1
	jne	record_node_without_arguments_part

	movzx	rdx,word ptr [rax-2+2]
 .if COPY_RECORDS_WITHOUT_POINTERS_TO_END_OF_HEAP
	sub	rdx,1
 .else
	test	rdx,rdx 
	je	copy_record_arguments_3b
	sub	rdx,1
	je	copy_record_arguments_3abb
 .endif

	lea	rcx,[rbp+rbx*8+3*8]
	push	rcx 
	push	rdx 

	sub	rbx,rbx 
	att_call	copy_lp2
	
	add	rbp,8
	pop	rbx 
	dec	rbx 
	att_call	copy_lp2

	pop	rbp 
	att_jmp	copy_lp1

 .if ! COPY_RECORDS_WITHOUT_POINTERS_TO_END_OF_HEAP
copy_record_arguments_3abb:
	push	rbx 
	sub	rbx,rbx 
	
	call	copy_lp2
	
	pop	rbx 
	
	lea	rbp,[rbp+rbx*8+2*8]
	jmp	copy_lp1

copy_record_arguments_3b:
	lea	rbp,[rbp+rbx*8+3*8]
	jmp	copy_lp1
 .endif

record_node_without_arguments_part:
	and	qword ptr [rbp+8],-2

 .if ! COPY_RECORDS_WITHOUT_POINTERS_TO_END_OF_HEAP
	cmp	word ptr [rax-2+2],0
	je	record_node_without_arguments_part_3b
 .endif

	sub	rbx,rbx 
	att_call	copy_lp2

	add	rbp,8
	att_jmp	copy_lp1

 .if ! COPY_RECORDS_WITHOUT_POINTERS_TO_END_OF_HEAP
record_node_without_arguments_part_3b:
	add	rbp,16
	jmp	copy_lp1
 .endif

not_in_hnf_1:
	movsxd	rbx,dword ptr [rax-4]
	cmp	rbx,257
	jge	copy_unboxed_closure_arguments
	sub	rbx,1
	att_jg	copy_lp2_lp1

copy_node_arity1:
	xor	rbx,rbx 
	att_call	copy_lp2

	add	rbp,8
	att_jmp	copy_lp1

copy_unboxed_closure_arguments:
	je	copy_unboxed_closure_arguments1

	xor	rax,rax
	mov	al,bh 
	and	rbx,255
	sub	rbx,rax 

	sub	rbx,1
	jl	copy_unboxed_closure_arguments_without_pointers
	
	push	rax 
	att_call	copy_lp2
	pop	rax 

copy_unboxed_closure_arguments_without_pointers:
	lea	rbp,[rbp+rax*8]
	att_jmp	copy_lp1

copy_unboxed_closure_arguments1:
	add	rbp,16
	att_jmp	copy_lp1

copy_array_21:
	mov	rbx,qword ptr [rbp+8]
	add	rbp,16
	test	rbx,rbx 
	je	copy_array_21_a

	movzx	rax,word ptr [rbx-2]
	movzx	rbx,word ptr [rbx-2+2]
	sub	rax,256
	test	rbx,rbx 
	je	copy_array_21_b

	cmp	rbx,rax 
	je	copy_array_21_r_a

copy_array_21_ab:
	cmp	qword ptr [rbp-16],0
	att_je	copy_lp1

	sub	rax,rbx 
	shl	rax,3
	sub	rbx,1

	push	rbx 
	push	rax 
	mov	rbx,qword ptr [rbp-16]
	sub	rbx,1
	push	rbx 

copy_array_21_lp_ab:
	mov	rbx,qword ptr [rsp+16]
	att_call	copy_lp2

	add	rbp,qword ptr [rsp+8]
	sub	qword ptr [rsp],1
	att_jnc	copy_array_21_lp_ab
	
	add	rsp,24
	att_jmp	copy_lp1

copy_array_21_b:
	mov	rbx,qword ptr [rbp-16]
	imul	rbx,rax 
	lea	rbp,[rbp+rbx*8]
	att_jmp	copy_lp1

copy_array_21_r_a:
	mov	rbx,qword ptr [rbp-16]
	imul	rbx,rax
	sub	rbx,1
	att_jc	copy_lp1
	att_jmp	copy_lp2_lp1

copy_array_21_a:
	mov	rbx,qword ptr [rbp-16]
	sub	rbx,1
	att_jc	copy_lp1
	att_jmp	copy_lp2_lp1

/* */
/*	Copy nodes to the other semi-space */
/* */

copy_lp2:
	mov	rdx,qword ptr [rbp]

/* selectors: */
continue_after_selector_2:
	mov	rcx,qword ptr [rdx]
	test	cl,2
	je	not_in_hnf_2

in_hnf_2:
	movzx	rax,word ptr [rcx-2]
	test	rax,rax
	je	copy_arity_0_node2

	cmp	rax,256
	jae	copy_record_2

	sub	rax,2
	mov	[rbp],rdi 

	lea	rbp,[rbp +8]
	ja	copy_hnf_node2_3

	mov	[rdi],rcx
	jb	copy_hnf_node2_1

	inc	rdi
	mov	rcx,[rdx+8]

	mov	[rdx],rdi 
	mov	rax,[rdx+16]

	sub	rbx,1
	mov	[rdi+8-1],rcx 

	mov	[rdi+16-1],rax 
	lea	rdi,[rdi+24-1]

	att_jae	copy_lp2
	ret

copy_hnf_node2_1:
	inc	rdi 
	mov	rax,[rdx+8]

	sub	rbx,1
	mov	[rdx],rdi

	mov	[rdi+8-1],rax 
	lea	rdi,[rdi+16-1]

	att_jae	copy_lp2
	ret

copy_hnf_node2_3:
	mov	[rdi],rcx 
	inc	rdi 

	mov	[rdx],rdi 
	mov	rcx,[rdx+8]

	mov	[rdi+8-1],rcx 
	mov	rcx,[rdx+16]

	add	rdi,24-1
	mov	rdx,[rcx]
	
	test	dl,1
	jne	arguments_already_copied_2

	mov	[rdi-8],rdi 
	add	rcx,8

	mov	[rdi],rdx 
	inc	rdi

	mov	[rcx-8],rdi 
	add	rdi,8-1

cp_hnf_arg_lp2:
	mov	rdx,[rcx]
	add	rcx,8

	mov	[rdi],rdx 
	add	rdi,8

	dec	rax 
	att_jne	cp_hnf_arg_lp2

	sub	rbx,1
	att_jae	copy_lp2
	ret

arguments_already_copied_2:
	mov	[rdi-8],rdx 

	sub	rbx,1
	att_jae	copy_lp2
	ret

copy_arity_0_node2:
	lea	r9,[rip+__STRING__+2]
	cmp	rcx,r9
	jbe	copy_string_or_array_2

	lea	r9,[rip+CHAR+2]
	cmp	rcx,r9
	ja	copy_normal_hnf_0_2

copy_int_bool_or_char_2:
	mov	rax,[rdx+8]
	je	copy_char_2

	lea	r9,[rip+dINT+2]
	cmp	rcx,r9
	jne	no_small_int_or_char_2

copy_int_2:
	cmp	rax,33
	att_jae	no_small_int_or_char_2

	shl	rax,4
	add	rbp,8

	lea	r9,[rip+small_integers]
	add	rax,r9
	sub	rbx,1

	mov	[rbp-8],rax 
	att_jae	copy_lp2
	ret

copy_char_2:	
	and	rax,255

	shl	rax,4
	add	rbp,8

	lea	r9,[rip+static_characters]
	add	rax,r9
	sub	rbx,1

	mov	[rbp-8],rax 
	att_jae	copy_lp2
	ret
	
no_small_int_or_char_2:
 .if COPY_RECORDS_WITHOUT_POINTERS_TO_END_OF_HEAP
copy_record_node2_1_b:
 .endif
	mov	[rsi-16],rcx 
	add	rbp,8

	mov	[rsi-8],rax 
	sub	rsi,15

	mov	[rdx],rsi 
	dec	rsi

	mov	[rbp-8],rsi

	sub	rbx,1
	att_jae	copy_lp2
	ret

copy_normal_hnf_0_2:
	sub	rcx,2-(-8)
	sub	rbx,1

	mov	[rbp],rcx 
	lea	rbp,[rbp+8]
	att_jae	copy_lp2
	ret

already_copied_2:
	dec	rcx 
	sub	rbx,1

	mov	[rbp],rcx 
	lea	rbp,[rbp+8]

	att_jae	copy_lp2
	ret

copy_record_2:
	sub	rax,258
	ja	copy_record_node2_3

 .if COPY_RECORDS_WITHOUT_POINTERS_TO_END_OF_HEAP
 	jb	copy_record_node2_1
 
 	cmp	word ptr [rcx-2+2],0
	att_je	copy_record_node2_bb

	mov	qword ptr [rbp],rdi
	mov	qword ptr [rdi],rcx

	lea	rcx,[rdi+1]
	mov	rax,qword ptr [rdx+8]

	mov	qword ptr [rdx],rcx

	mov	qword ptr [rdi+8],rax
	mov	rax,qword ptr [rdx+16]

	add	rbp,8
	mov	qword ptr [rdi+16],rax

	add	rdi,24
	sub	rbx,1
	att_jae	copy_lp2
	ret

copy_record_node2_1:
	mov	rax,qword ptr [rdx+8]

	cmp	word ptr [rcx-2+2],0
	att_je	copy_record_node2_1_b

	mov	qword ptr [rbp],rdi
	mov	qword ptr [rdi],rcx

	lea	rcx,[rdi+1]
	mov	qword ptr [rdi+8],rax

	mov	qword ptr [rdx],rcx
	add	rbp,8

	add	rdi,16
	sub	rbx,1
	att_jae	copy_lp2
	ret

copy_record_node2_bb:
	mov [rsi-24],rcx 
	sub	rsi,24-1

	mov	[rdx],rsi 
	dec	rsi 

	mov	rax,[rdx+8]
	mov	rcx,[rdx+16]

	mov	[rbp],rsi 
	add	rbp,8

	mov	[rsi+8],rax 
	sub	rbx,1

	mov [rsi+16],rcx 

	att_jae	copy_lp2
	ret

 .else
	mov	qword ptr [rbp],rdi
	mov	qword ptr [rdi],rcx

	lea	rcx,[rdi+1]
	mov	rax,qword ptr [rdx+8]

	mov	qword ptr [rdx],rcx
	jb	copy_record_node2_1

	mov	qword ptr [rdi+8],rax
	mov	rax,qword ptr [rdx+16]

	add	rbp,8
	mov	qword ptr [rdi+16],rax

	add	rdi,24
	sub	rbx,1
	jae	copy_lp2
	ret

copy_record_node2_1:
	add	rbp,8
	mov	qword ptr [rdi+8],rax 

	add	rdi,16
	sub	rbx,1
	jae	copy_lp2
	ret
 .endif

copy_record_node2_3:
 .if COPY_RECORDS_WITHOUT_POINTERS_TO_END_OF_HEAP
 	cmp	word ptr [rcx-2+2],1
 	jbe	copy_record_node2_3_ab_or_b
 .endif

	push	rax 
	lea	rax,[rdi+1]
	
	mov	qword ptr [rdx],rax 
	mov	rax,qword ptr [rdx+16]

	mov	qword ptr [rdi],rcx 
	mov	rdx,qword ptr [rdx+8]

 .if COPY_RECORDS_WITHOUT_POINTERS_TO_END_OF_HEAP
	mov	qword ptr [rdi+8],rdx 
	mov	qword ptr [rbp],rdi
	add	rbp,8

	mov	rcx,rax
	test	byte ptr [rax],1		
	jne	record_arguments_already_copied_2
 .else
	mov	rcx,rax 
	sub	rax,qword ptr heap_p1

	shr	rax,4
	mov	qword ptr [rdi+8],rdx 

	mov	rdx,rax 
	and	rax,31

	shr	rdx,3
	mov	qword ptr [rbp],rdi

	and	rdx,-4
	mov	eax,dword ptr [rax*4+bit_set_table]

	add	rdx,qword ptr heap_copied_vector
	add	rbp,8

	test	eax,[rdx]
	jne	record_arguments_already_copied_2

	or	[rdx],eax
 .endif
	lea	rdx,[rdi+24]

	pop	rax
	mov	qword ptr [rdi+16],rdx

	add	rdi,25
	mov	rdx,qword ptr [rcx]

	mov	qword ptr [rcx],rdi
	add	rcx,8

	mov	qword ptr [rdi-1],rdx
	add	rdi,7

cp_record_arg_lp2:
	mov	rdx,qword ptr [rcx]
	add	rcx,8

	mov	qword ptr [rdi],rdx
	add	rdi,8

	sub	rax,1
	att_jne	cp_record_arg_lp2

	sub	rbx,1
	att_jae	copy_lp2
	ret

record_arguments_already_copied_2:
	mov	rdx,qword ptr [rcx]
	pop	rax 

	mov	qword ptr [rdi+16],rdx 
	add	rdi,24

	sub	rbx,1
	att_jae	copy_lp2
	ret

 .if COPY_RECORDS_WITHOUT_POINTERS_TO_END_OF_HEAP
copy_record_node2_3_ab_or_b:
	jb	copy_record_node2_3_b

	push	rax
	lea	rax,[rdi+1]

	mov	qword ptr [rdx],rax 
	mov	rax,qword ptr [rdx+16]

	mov	qword ptr [rdi],rcx 
	mov	rdx,qword ptr [rdx+8]

	mov	rcx,rax 
	sub	rax,qword ptr [rip+heap_p1]

	shr	rax,4
	mov	qword ptr [rdi+8],rdx 

	mov	rdx,rax 
	and	rax,31

	shr	rdx,3
	mov	qword ptr [rbp],rdi

	and	rdx,-4
	lea	r9,[rip+bit_set_table]
	mov	eax,dword ptr [r9+rax*4]

	add	rdx,qword ptr [rip+heap_copied_vector]
	add	rbp,8

	test	eax,[rdx]
	att_jne	record_arguments_already_copied_2

	or	[rdx],eax
	pop	rax

	sub	rsi,8

	shl	rax,3
	sub	rsi,rax
	
	push	rsi
	add	rsi,1
	
	mov	qword ptr [rdi+16],rsi
	add	rdi,24
	
	mov	rdx,qword ptr [rcx]
	jmp	cp_record_arg_lp3_c

copy_record_node2_3_b:
	push	rax
	lea	rax,[rsi-24+1]

	mov	qword ptr [rdx],rax 
	mov	rax,qword ptr [rdx+16]

	mov	qword ptr [rsi-24],rcx 
	mov	rdx,qword ptr [rdx+8]

	mov	rcx,rax 
	sub	rax,qword ptr [rip+heap_p1]

	shr	rax,4
	mov	qword ptr [rsi-16],rdx 

	mov	rdx,rax 
	and	rax,31
	sub	rsi,24

	shr	rdx,3
	mov	qword ptr [rbp],rsi

	and	rdx,-4
	lea	r9,[rip+bit_set_table]
	mov	eax,dword ptr [r9+rax*4]

	add	rdx,qword ptr [rip+heap_copied_vector]
	add	rbp,8

	test	eax,[rdx]
	jne	record_arguments_already_copied_3_b

	or	[rdx],eax
	pop	rax

	mov	rdx,rsi
	sub	rsi,8

	shl	rax,3
	sub	rsi,rax

	mov	qword ptr [rdx+16],rsi

	mov	rdx,qword ptr [rcx]

	push	rsi
	add	rsi,1

cp_record_arg_lp3_c:
	mov	qword ptr [rcx],rsi
	add	rcx,8
	mov	qword ptr [rsi-1],rdx
	add	rsi,7

cp_record_arg_lp3:
	mov	rdx,qword ptr [rcx]
	add	rcx,8
	
	mov	qword ptr [rsi],rdx
	add	rsi,8
	
	sub	rax,8
	att_jne	cp_record_arg_lp3
	
	pop	rsi

	sub	rbx,1
	att_jae	copy_lp2
	ret

record_arguments_already_copied_3_b:
	mov	rdx,qword ptr [rcx]
	pop	rax
	
	sub	rdx,1
	mov	qword ptr [rsi+16],rdx
	
	sub	rbx,1
	att_jae	copy_lp2
	ret
 .endif

not_in_hnf_2:
	test	cl,1
	att_jne	already_copied_2

	movsxd	rax,dword ptr [rcx-4]
	test	rax,rax 
	jle	copy_arity_0_node2_

copy_node2_1_:
	and	rax,255
	sub	rax,2
	jl	copy_arity_1_node2
copy_node2_3:
	mov	[rbp],rdi 
	add	rbp,8
	mov	[rdi],rcx 
	inc	rdi
	mov	[rdx],rdi
	mov	rcx,[rdx+8]
	add	rdx,16
	mov [rdi+8-1],rcx 
	add	rdi,16-1

cp_arg_lp2:
	mov	rcx,[rdx]
	add	rdx,8
	mov	[rdi],rcx 
	add	rdi,8
	sub	rax,1
	att_jae	cp_arg_lp2

	sub	rbx,1
	att_jae	copy_lp2
	ret

copy_arity_1_node2:
copy_arity_1_node2_:
	mov	[rbp],rdi 
	inc	rdi 

	add	rbp,8
	mov	[rdx],rdi 

	mov	rax,[rdx+8]
	mov [rdi-1],rcx 

	mov [rdi+8-1],rax 
	add	rdi,24-1

	sub	rbx,1
	att_jae	copy_lp2
	ret

copy_indirection_2:
	mov	rax,rdx 
	mov	rdx,[rdx+8]

	mov	rcx,[rdx]
	test	cl,2
	att_jne	in_hnf_2

	test	cl,1
	att_jne	already_copied_2

	cmp	dword ptr [rcx-4],-2
	je	skip_indirections_2

	movsxd	rax,dword ptr [rcx-4]
	test	rax,rax 
	att_jle	copy_arity_0_node2_
	att_jmp	copy_node2_1_

skip_indirections_2:
	mov	rdx,[rdx+8]

	mov	rcx,[rdx]
	test	cl,2
	jne	update_indirection_list_2
	test	cl,1
	att_jne	update_indirection_list_2

	cmp	dword ptr [rcx-4],-2
	att_je	skip_indirections_2

update_indirection_list_2:
	lea	rcx,[rax+8]
	mov	rax,[rax+8]
	mov	[rcx],rdx 
	cmp	rdx,rax 
	att_jne	update_indirection_list_2

	att_jmp	continue_after_selector_2

copy_selector_2:
	cmp	rax,-2
	att_je	copy_indirection_2
	jl	copy_record_selector_2

	mov	rax,[rdx+8]

	mov	r10,[rax]
	test	r10b,2
 	att_je	copy_arity_1_node2_

	movsxd	r11,dword ptr [rcx-8]

	cmp	word ptr [r10-2],2
	jbe	copy_selector_2_
 
 	mov	r10,[rax+16]

	test	byte ptr [r10],1
	att_jne	copy_arity_1_node2_

	movzx	r11,word ptr [rcx+r11+4-8]
	lea	r9,[rip+__indirection]
	mov	qword ptr [rdx],r9

	cmp	r11,16
	jl	copy_selector_2_1
	je	copy_selector_2_2

	mov	rcx,qword ptr [r10+r11-24]
	mov	qword ptr [rdx+8],rcx
	mov	rdx,rcx
	att_jmp	continue_after_selector_2

copy_selector_2_1:
	mov	rcx,qword ptr [rax+8]
	mov	qword ptr [rdx+8],rcx
	mov	rdx,rcx
	att_jmp	continue_after_selector_2

copy_selector_2_2:
	mov	rcx,qword ptr [r10]
	mov	qword ptr [rdx+8],rcx
	mov	rdx,rcx
	att_jmp	continue_after_selector_2

copy_selector_2_:
	movzx	r11,word ptr [rcx+r11+4-8]
	lea	r9,[rip+__indirection]
	mov	qword ptr [rdx],r9

	mov	rcx,qword ptr [rax+r11]
	mov	qword ptr [rdx+8],rcx
	mov	rdx,rcx
	att_jmp	continue_after_selector_2

copy_record_selector_2:
	cmp	rax,-3
 	mov	rax,qword ptr [rdx+8]
	mov	r10,qword ptr [rax]
	je	copy_strict_record_selector_2

 	test	r10b,2
	att_je	copy_arity_1_node2_

	movsxd	r11,dword ptr [rcx-8]

	cmp	word ptr [r10-2],258
	jbe	copy_record_selector_2_

 .if COPY_RECORDS_WITHOUT_POINTERS_TO_END_OF_HEAP
	cmp	word ptr [r10-2+2],2
	jae	copy_selector_2__
 .endif

	mov	r12,qword ptr [rax+16]

	lea	r10,[r12-24]
	sub	r12,qword ptr [rip+heap_p1]

	mov	r13,r12 
	and	r12,31*16

	shr	r13,7
	
	shr	r12,2
	and	r13,-4

	add	r13,qword ptr [rip+heap_copied_vector]

	lea	r9,[rip+bit_set_table]
	mov	r12d,dword ptr [r9+r12]

	and	r12d,dword ptr [r13]
 .if COPY_RECORDS_WITHOUT_POINTERS_TO_END_OF_HEAP
	att_je	copy_record_selector_2_
	att_jmp	copy_arity_1_node2_
copy_selector_2__:
	mov	r12,qword ptr [rax+16]
	lea	r10,[r12-24]
	test	byte ptr [r12],1
	att_jne	copy_arity_1_node2_	
 .else
	jne	copy_arity_1_node2_
 .endif
copy_record_selector_2_:
	movzx	r11,word ptr [rcx+r11+4-8]
	lea	r9,[rip+__indirection]
	mov	qword ptr [rdx],r9

	cmp	r11,16
	jle	copy_record_selector_3
	mov	rax,r10
copy_record_selector_3:
	mov	rcx,qword ptr [rax+r11]
	mov	qword ptr [rdx+8],rcx
	mov	rdx,rcx
	att_jmp	continue_after_selector_2

copy_strict_record_selector_2:
	test	r10b,2
	att_je	copy_arity_1_node2_

	movsxd	r11,dword ptr [rcx-8]

	cmp	word ptr [r10-2],258
	jbe	copy_strict_record_selector_2_

 .if COPY_RECORDS_WITHOUT_POINTERS_TO_END_OF_HEAP
	cmp	word ptr [r10-2+2],2
	jb	copy_strict_record_selector_2_b

	mov	r12,qword ptr [rax+16]
	lea	r10,[r12-24]
	test	byte ptr [r12],1
	att_jne	copy_arity_1_node2_	

	att_jmp	copy_strict_record_selector_2_

copy_strict_record_selector_2_b:
 .endif

	mov	r12,qword ptr [rax+16]

	lea	r10,[r12-24]
	sub	r12,qword ptr [rip+heap_p1]

	mov	r13,r12 
	and	r12,31*16

	shr	r13,7

	shr	r12,2
	and	r13,-4

	add	r13,qword ptr [rip+heap_copied_vector]

	lea	r9,[rip+bit_set_table]
	mov	r12d,dword ptr [r9+r12]
	
	and	r12d,[r13]

	att_jne	copy_arity_1_node2_

copy_strict_record_selector_2_:
	add	r11,rcx
	movzx	rcx,word ptr [r11+4-8]
	cmp	rcx,16
	jle	copy_strict_record_selector_3
	mov	rcx,qword ptr [r10+rcx]
	jmp	copy_strict_record_selector_4
copy_strict_record_selector_3:
	mov	rcx,qword ptr [rax+rcx]
copy_strict_record_selector_4:
	mov	qword ptr [rdx+8],rcx

	movzx	rcx,word ptr [r11+6-8]
	test	rcx,rcx
	je	copy_strict_record_selector_6
	cmp	rcx,16
	jle	copy_strict_record_selector_5
	mov	rax,r10
copy_strict_record_selector_5:
	mov	rcx,qword ptr [rax+rcx]
	mov	qword ptr [rdx+16],rcx
copy_strict_record_selector_6:

	mov	rcx,qword ptr [r11-8-8]
	mov	qword ptr [rdx],rcx
	att_jmp	in_hnf_2

copy_arity_0_node2_:
	att_jl	copy_selector_2

	mov [rsi-24],rcx 
	sub	rsi,24
	mov	[rbp],rsi 
	lea	rax,[rsi+1]

	add	rbp,8
	mov	[rdx],rax 

	sub	rbx,1
	att_jae	copy_lp2
	ret

copy_string_or_array_2:
	mov	rcx,rdx 
	jne	copy_array_2

	sub	rdx,[rip+heap_p1]
	cmp	rdx,[rip+semi_space_size]
	jae	copy_string_or_array_constant

	mov	rdx,[rcx+8]
	add	rbp,8

	add	rdx,7
	push	rbx

	mov	rax,rdx 
	and	rdx,-8
	
	shr	rax,3
	sub	rsi,rdx 

	mov	rbx,[rcx]
	add	rcx,8

	mov [rsi-16],rbx 
	sub	rsi,16

	mov [rbp-8],rsi 
	lea	rdx,[rsi+1]
	
	mov [rcx-8],rdx 
	lea	rdx,[rsi+8]

cp_s_arg_lp2:
	mov	rbx,[rcx]
	add	rcx,8

	mov	[rdx],rbx 
	add	rdx,8

	sub	rax,1
	att_jge	cp_s_arg_lp2

	pop	rbx 
	sub	rbx,1
	att_jae	copy_lp2
	ret

copy_array_2:
	sub	rdx,[rip+heap_p1]
	cmp	rdx,[rip+semi_space_size]
	att_jae	copy_string_or_array_constant

	push	rbx 

	mov	rax,qword ptr [rcx+16]
	test	rax,rax 
	je	copy_array_a2

	movzx 	rbx,word ptr [rax-2]

	test	rbx,rbx 
	je	copy_strict_basic_array_2
	
	sub	rbx,256
	imul	rbx,qword ptr [rcx+8]
	jmp	copy_array_a3

copy_array_a2:
	mov	rbx,qword ptr [rcx+8]
copy_array_a3:
	mov	rdx,rdi 
	lea	rdi,[rdi+rbx*8+24]

	mov	qword ptr [rbp],rdx 
	mov	rax,qword ptr [rcx]

	add	rbp,8
	mov	qword ptr [rdx],rax 

	lea	rax,[rdx+1]
	add	rdx,8

	mov	qword ptr [rcx],rax 
	add	rcx,8

	lea	rax,[rbx+1]
	att_jmp	cp_s_arg_lp2

copy_strict_basic_array_2:
	mov	rbx,qword ptr [rcx+8]

	lea	r9,[rip+dINT+2]
	cmp	rax,r9
	jle	copy_int_or_real_array_2

	lea	r9,[rip+BOOL+2]
	cmp	rax,r9
	je	copy_bool_array_2

copy_int32_or_real32_array_2:
	add	rbx,1
	shr	rbx,1

copy_int_or_real_array_2:
	shl	rbx,3
	lea	rdx,[rsi-24]

	sub	rdx,rbx 
	mov	rax,qword ptr [rcx]

	shr	rbx,3
	mov	qword ptr [rbp],rdx 

	add	rbp,8
	mov	rsi,rdx 
	
	mov	qword ptr [rdx],rax 
	lea	rax,[rdx+1]

	add	rdx,8
	mov	qword ptr [rcx],rax 

	add	rcx,8
	lea	rax,[rbx+1]
	att_jmp	cp_s_arg_lp2

copy_bool_array_2:
	add	rbx,7
	shr	rbx,3
	att_jmp	copy_int_or_real_array_2

copy_string_or_array_constant:
	mov	qword ptr [rbp],rcx 
	add	rbp,8

	sub	rbx,1
	att_jae	copy_lp2
	ret

end_copy1:
	mov [rip+heap_end_after_gc],rsi 

	lea	rcx,[rip+finalizer_list]
	lea	rdx,[rip+free_finalizer_list]
	mov	rbp,qword ptr [rip+finalizer_list]

determine_free_finalizers_after_copy:
	mov	rax,qword ptr [rbp]
	test	al,1
	je	finalizer_not_used_after_copy

	mov	rbp,qword ptr [rbp+8]
	sub	rax,1
	mov	qword ptr [rcx],rax 
	lea	rcx,[rax+8]
	att_jmp	determine_free_finalizers_after_copy

finalizer_not_used_after_copy:
	lea	r9,[rip+__Nil-8]
	cmp	rbp,r9
	je	end_finalizers_after_copy

	mov	qword ptr [rdx],rbp 
	lea	rdx,[rbp+8]
	mov	rbp,qword ptr [rbp+8]
	att_jmp	determine_free_finalizers_after_copy	

end_finalizers_after_copy:
	mov	qword ptr [rcx],rbp 
	mov	qword ptr [rdx],rbp