implementation module Yard

import StdTuple
import StdClass
import StdString
import StdList
import StdInt

import Common

concat :: ([String] -> String)
concat = foldl (+++) ""

intersperse :: !a ![a] -> [a]
intersperse i []      = []
intersperse i [x]     = [x]
intersperse i [x:xs]  = [x,i:intersperse i xs]

runParser :: (Parser a b) [a] -> (Either Error b, [a])
runParser (Parser f) i = f i
 
instance Functor (Parser a) where
	(<$>) f m = m >>= \x -> pure (f x)

instance Applicative (Parser a) where
	pure a	  = Parser \i -> (Right a, i)
	(<*>) sf p  = sf >>= \sf` -> p >>= \p` -> pure (sf` p`)

instance Monad (Parser a) where
	(>>=) p f	= Parser \i -> case runParser p i of
		(Right r, rest) = runParser (f r) rest
		(Left e, _)	 = (Left e, i)

instance Alternative (Parser a) where
	empty	   = Parser \i -> (Left $ GenericError "" , i)
	(<|>) p1 p2 = Parser \i -> case runParser p1 i of
		(Right r, rest) = (Right r, rest)
		(Left e1, rest) = case runParser p2 i of
			(Left e2, rest)  = (Left e2, i)
			(Right r, rest)  = (Right r, rest)

(<?>) :: (Parser a b) Error -> Parser a b
(<?>) p e = Parser \i -> case runParser p i of
	(Left e1, rest) = (Left e, rest)
	(Right r, rest) = (Right r, rest)

fail :: Parser a b
fail = empty

top :: Parser a a
top = Parser \i -> case i of
	[]	  = (Left $ GenericError "", [])
	[x:xs]  = (Right x, xs)

peek :: Parser a a
peek = Parser \i -> case i of
	[]	  = (Left $ GenericError "", [])
	[x:xs]  = (Right x, [x:xs])

(until) infix 2 :: (Parser a b) (Parser a c) -> Parser a [b]
(until) p guard = try $ until` p guard [] 
	where
		until` :: (Parser a b) (Parser a c) [b] -> Parser a [b]
		until` p guard acc = Parser \i -> case runParser guard i of 
			(Right _, rest) = (Right acc, rest)
			(Left _, _)	 = case runParser p i of
				(Right r, rest) = runParser (until` p guard [r:acc]) rest
				(Left e, _)	 = (Left e, i)
		try :: (Parser a b) -> Parser a b
		try p = Parser \i -> case runParser p i of
			(Left e, _)	 = (Left e, i)
			(Right r, rest) = (Right r, rest)

satisfy :: (a -> Bool) -> Parser a a
satisfy f = top >>= \r -> if (f r) (pure r) fail

check :: (a -> Bool) -> Parser a a
check f = peek >>= \r -> if (f r) (pure r) fail

item :: a -> Parser a a | == a
item a  = satisfy ((==)a)

list :: [a] -> Parser a [a] | == a
list as = mapM item as