implementation module QA_shapes

import QA, StdReal

//	deze module definieert een aantal eenvoudige vorm-naam elementen

d    :== px 40.0
font :== normalFontDef "Times" 40.0

queries :: [QA]
queries
	= [(rect d d,                                      "square")
	  ,(circle d <@< {strokewidth=zero},               "circle")
	  ,(ellipse d (d /. 2) <@< {strokewidth=zero},     "ellipse")
	  ,(text font "Hello",                             "text")
	  ,(margin (d /. 2,px zero) (xline Nothing d),     "xline")
	  ,(margin (px zero,d /. 2) (yline Nothing d),     "yline")
	  ,(line Nothing Slash d d,                        "slash")
	  ,(line Nothing Backslash d d,                    "backslash")
	  ,(polygon  Nothing [(d/.2,zero),(d,d),(zero,d)], "triangle")
	  ,(polyline Nothing [(d/.2,zero),(d,d),(zero,d),(d/.2,zero)], "polyline")
	  ,(fitx (d /. 1.2) 
	      (overlay [(AtMiddleX,AtMiddleY),(AtMiddleX,AtMiddleY)] 
	               [] 
	               [rect d d,rotate (deg 45.0) (rect d d)] 
	               Nothing),                           "star")
	  ]