# Sil

A compiler for the simple imperative language sil.
This compiler is written in [Clean][clean] and compiles to [ABC-assembly][abc],
which can be used to generate actual machine code using Clean's code generator
or can be interpreted with the [ABCMachine][abc-github] project.

## Grammar

```
<Program>        ::= <Function>-list

<Function>       ::= <Type> <Name> '(' <Arg>-clist ')' '{' <CodeBlock> '}'

<CodeBlock>      ::= <Initialisation>-list <Statement>-list

<Initialisation> ::= <Type> <InitName>-clist ';'

<InitName>       ::= <Name> [':=' <Expression>]

<Statement>      ::= [<Name> ':='] <Expression> ';'
                  |  'return' [<Expression>] ';'
                  |  'if' '(' <Expression> ')' '{' <CodeBlock> '}'
                         ['else' 'if' '(' <Expression> ')' '{' <CodeBlock> '}']-list
                         ['else' '{' <CodeBlock> '}']
                  |  'while' '(' <Expression> ')' '{' <CodeBlock> '}'
                  |  '|~' <MachineCode>

<Expression>     ::= <Name>
                  |  <Literal>
                  |  <Name> '(' <Expression>-clist ')'
                  |  <Op1> <Expression>
                  |  <Expression> <Op2> <Expression>
                  |  '(' <Expression>-clist ')'
                  |  '(' <Expression> ')'
                  |  <Expression> '.' <Name>

<Op1>            ::= '~' | '!'
<Op2>            ::= '+' | '-' | '*' | '/' | '%' | '==' | '||' | '&&'

<Type>           ::= 'Bool' | 'Int' | 'Void'

<Literal>        ::= <Bool> | <Int>
<Bool>           ::= 'True' | 'False'
<Int>            ::= <Digit>-list
```

Comments (single-line `//`, multi-line `/* ... */`) are not included in the
grammar above.

## Dependencies

You need a working Clean installation to build the compiler and at least `clm`
and the code generator to use it.

## Vim highlighting

In the `vim` directory.

## Author &amp; License

Copyright &copy; 2017 [Camil Staps][cs].
Licensed under MIT, see the `LICENSE` file.

[abc]: https://en.wikipedia.org/wiki/Clean_%28programming_language%29#The_ABC-Machine
[abc-github]: https://github.com/camilstaps/ABCMachine
[clean]: http://clean.cs.ru.nl
[cs]: https://camilstaps.nl