target triple = "x86_64-pc-linux-gnu"

declare i8* @malloc(i64)

declare i64 @printf(i8*, ...)
@printf_d = private unnamed_addr constant [3 x i8] c"%d\00", align 1
@printf_c = private unnamed_addr constant [3 x i8] c"%c\00", align 1
@printf_cycle = private unnamed_addr constant [16 x i8] c"cycle in spine\0a\00", align 1
@printf_gc = private unnamed_addr constant [11 x i8] c"heap full\0a\00", align 1

attributes #0 = { alwaysinline }

%Hp = type {i64*,i64}

define private i64* @_alloc_heap(i64 %n) alwaysinline {
  %s.0 = alloca i64
  %s.1 = getelementptr i64, i64* %s.0, i64 1
  %s.0.0 = ptrtoint i64* %s.0 to i64
  %s.1.0 = ptrtoint i64* %s.1 to i64
  %s.2 = sub i64 %s.1.0, %s.0.0
  %s.3 = mul i64 %s.2, %n
  %r.0 = call i8* @malloc(i64 %s.3)
  %r.1 = bitcast i8* %r.0 to i64*
  ret i64* %r.1
}

define private i64** @_alloc_a_stack(i64 %n) alwaysinline {
  %s.0 = alloca i64*
  %s.1 = getelementptr i64*, i64** %s.0, i64 1
  %s.0.0 = ptrtoint i64** %s.0 to i64
  %s.1.0 = ptrtoint i64** %s.1 to i64
  %s.2 = sub i64 %s.1.0, %s.0.0
  %s.3 = mul i64 %s.2, %n
  %r.0 = call i8* @malloc(i64 %s.3)
  %r.1 = bitcast i8* %r.0 to i64**
  ret i64** %r.1
}

define private i64** @_push_local_astack(i64** %asp.0, i64** %aspstart, i64** %globasp.0) #0 {
entry:
  br label %loop

loop:
  %asp = phi i64** [%asp.0, %entry], [%asp.1, %loop.0]
  %globasp = phi i64** [%globasp.0, %entry], [%globasp.1, %loop.0]
  %t.0 = icmp eq i64** %asp, %aspstart
  br i1 %t.0, label %done, label %loop.0
done:
  ret i64** %globasp

loop.0:
  %globasp.1 = getelementptr i64*, i64** %globasp, i64 1
  %n = load i64*, i64** %asp
  store i64* %n, i64** %globasp.1
  %asp.1 = getelementptr i64*, i64** %asp, i64 -1
  br label %loop
}

define private i64** @_pop_global_astack(i64** %asp, i64** %aspstart.0, i64** %globasp.0) noinline optnone {
entry:
  br label %loop

loop:
  %aspstart = phi i64** [%aspstart.0, %entry], [%aspstart.1, %loop.0]
  %globasp = phi i64** [%globasp.0, %entry], [%globasp.1, %loop.0]
  %t.0 = icmp eq i64** %aspstart, %asp
  br i1 %t.0, label %done, label %loop.0
done:
  ret i64** %globasp

loop.0:
  %n = load i64*, i64** %globasp
  %aspstart.1 = getelementptr i64*, i64** %aspstart, i64 1
  store i64* %n, i64** %aspstart.1
  %globasp.1 = getelementptr i64*, i64** %globasp, i64 -1
  br label %loop
}

define private %Hp @_need_free_words(i64 %n, %Hp %hp_s.0) #0 {
  %hp_free.0 = extractvalue %Hp %hp_s.0, 1
  %hp_free.1 = sub i64 %hp_free.0, %n

  %lt = icmp slt i64 %hp_free.1, 0
  br i1 %lt, label %gc, label %ok
ok:
  %hp_s.1 = insertvalue %Hp %hp_s.0, i64 %hp_free.1, 1
  ret %Hp %hp_s.1

gc:
  ; TODO
  call i64 (i8*, ...) @printf(i8* getelementptr inbounds ([11 x i8], [11 x i8]* @printf_gc, i64 0, i64 0))
  unreachable
}

define private i64* @addI(i64* %bsp.0) #0 {
  %t.0 = load i64, i64* %bsp.0
  store i64 undef, i64* %bsp.0
  %bsp.1 = getelementptr i64, i64* %bsp.0, i64 1
  %t.1 = load i64, i64* %bsp.1
  %t.2 = add i64 %t.0, %t.1
  store i64 %t.2, i64* %bsp.1
  ret i64* %bsp.1
}

define private {i64**,%Hp} @build(i64* %label, i64 %arity, i64** %asp.0, i64** %aspstart, i64** %globasp.0, %Hp %hp_s.0) #0 {
entry:
  %arity_p1 = add i64 %arity, 1
  %lt = icmp slt i64 %arity, 2
  br i1 %lt, label %arity_lt2, label %arity_ge2

arity_lt2:
  br label %arity_ge2

arity_ge2:
  %n_words = phi i64 [%arity_p1, %entry], [3, %arity_lt2]
  %hp_s.1 = call %Hp @_need_free_words(i64 %arity_p1, %Hp %hp_s.0)
  %hp.0 = extractvalue %Hp %hp_s.1, 0
  %hp_free.0 = extractvalue %Hp %hp_s.1, 1

  %label.0 = ptrtoint i64* %label to i64
  store i64 %label.0, i64* %hp.0
  %hp.1 = getelementptr i64, i64* %hp.0, i64 1
  br label %loop

loop:
  %asp.1 = phi i64** [%asp.0, %arity_ge2], [%asp.2, %loop.0]
  %hp.2 = phi i64* [%hp.1, %arity_ge2], [%hp.3, %loop.0]
  %arity.0 = phi i64 [%arity, %arity_ge2], [%arity.1, %loop.0]
  %t.0 = icmp eq i64 %arity.0, 0
  br i1 %t.0, label %done, label %loop.0
done:
  %asp.3 = getelementptr i64*, i64** %asp.1, i64 1
  store i64* %hp.0, i64** %asp.3
  %ret.0 = insertvalue {i64**,%Hp} undef, i64** %asp.3, 0
  %hp.4 = getelementptr i64, i64* %hp.0, i64 %n_words
  %hp_s.2 = insertvalue %Hp %hp_s.1, i64* %hp.4, 0
  %hp_s.3 = insertvalue %Hp %hp_s.2, i64 %hp_free.0, 1 ; TODO
  %ret.1 = insertvalue {i64**,%Hp} %ret.0, %Hp %hp_s.3, 1
  ret {i64**,%Hp} %ret.1

loop.0:
  %t.1 = call i64* @peek_a(i64** %asp.1)
  %asp.2 = call i64** @pop_a1(i64** %asp.1)
  %t.2 = ptrtoint i64* %t.1 to i64
  store i64 %t.2, i64* %hp.2
  %hp.3 = getelementptr i64, i64* %hp.2, i64 1
  %arity.1 = sub i64 %arity.0, 1
  br label %loop
}

define private {i64**,%Hp} @buildI(i64 %i, i64** %asp.0, %Hp %hp_s.0) #0 {
  %hp_s.1 = call %Hp @_need_free_words(i64 2, %Hp %hp_s.0)
  %hp.0 = extractvalue %Hp %hp_s.1, 0
  %hp_free.0 = extractvalue %Hp %hp_s.1, 1

  %INT.0 = bitcast {i64, i64, i64*, i64, i8, i8, i8}* @INT to i8*
  %INT.1 = getelementptr i8, i8* %INT.0, i64 2
  %INT.2 = ptrtoint i8* %INT.1 to i64
  store i64 %INT.2, i64* %hp.0

  %hp.1 = getelementptr i64, i64* %hp.0, i64 1
  store i64 %i, i64* %hp.1

  %asp.1 = getelementptr i64*, i64** %asp.0, i64 1
  store i64* %hp.0, i64** %asp.1

  %hp.2 = getelementptr i64, i64* %hp.0, i64 2
  %ret.0 = insertvalue {i64**,%Hp} undef, i64** %asp.1, 0
  %hp_s.2 = insertvalue %Hp %hp_s.1, i64* %hp.2, 0
  %ret.1 = insertvalue {i64**,%Hp} %ret.0, %Hp %hp_s.2, 1
  ret {i64**,%Hp} %ret.1
}

define private i64* @eqI_b(i64 %i, i64 %n, i64* %bsp.0) #0 {
  %bsp.1 = getelementptr i64, i64* %bsp.0, i64 %n
  %bsp.2 = getelementptr i64, i64* %bsp.0, i64 -1
  %t.0 = load i64, i64* %bsp.1
  %t.1 = icmp eq i64 %t.0, %i
  %t.2 = zext i1 %t.1 to i64
  store i64 %t.2, i64* %bsp.2
  ret i64* %bsp.2
}

define private i64** @fillI_b(i64 %b_offset, i64 %a_offset, i64* %bsp.0, i64** %asp.0) #0 {
  %bsp.1 = getelementptr i64, i64* %bsp.0, i64 %b_offset
  %t.0 = load i64, i64* %bsp.1

  %asp.1 = getelementptr i64*, i64** %asp.0, i64 %a_offset

  %n.0 = load i64*, i64** %asp.1
  %INT.0 = bitcast {i64, i64, i64*, i64, i8, i8, i8}* @INT to i8*
  %INT.1 = getelementptr i8, i8* %INT.0, i64 2
  %INT.2 = ptrtoint i8* %INT.1 to i64
  store i64 %INT.2, i64* %n.0

  %n.1 = getelementptr i64, i64* %n.0, i64 1
  store i64 %t.0, i64* %n.1

  ret i64** %asp.0
}

define private {%Hp,i64**} @jsr_eval(i64 %n, i64** %asp.0, i64** %aspstart, i64** %globasp.0, %Hp %hp.0) #0 {
  %asp.1 = getelementptr i64*, i64** %asp.0, i64 %n

  %n.0 = load i64*, i64** %asp.1
  %d.0 = load i64, i64* %n.0

  %t.0 = and i64 %d.0, 2
  %t.1 = icmp eq i64 %t.0, 0
  br i1 %t.1, label %eval, label %done

done:
  %r.0 = insertvalue {%Hp,i64**} undef, %Hp %hp.0, 0
  %r.1 = insertvalue {%Hp,i64**} %r.0, i64** %globasp.0, 1
  ret {%Hp,i64**} %r.1

eval:
  %globasp.1 = call i64** @_push_local_astack(i64** %asp.0, i64** %aspstart, i64** %globasp.0)
  %nentry.0 = inttoptr i64 %d.0 to {%Hp,i64**,i64*} (%Hp, i64**, i64*)*
  %t.2 = call cc101 {%Hp,i64**,i64*} %nentry.0(%Hp %hp.0, i64** %globasp.1, i64* %n.0)
  %hp.1 = extractvalue {%Hp,i64**,i64*} %t.2, 0
  %globasp.2 = extractvalue {%Hp,i64**,i64*} %t.2, 1
  %n.1 = extractvalue {%Hp,i64**,i64*} %t.2, 2
  %globasp.3 = call i64** @_pop_global_astack(i64** %asp.0, i64** %aspstart, i64** %globasp.2)
  store i64* %n.1, i64** %asp.1 ; TODO this may not be needed?

  %r.2 = insertvalue {%Hp,i64**} undef, %Hp %hp.1, 0
  %r.3 = insertvalue {%Hp,i64**} %r.2, i64** %globasp.3, 1
  ret {%Hp,i64**} %r.3
}

define private i64* @ltI(i64* %bsp.0) #0 {
  %t.0 = load i64, i64* %bsp.0
  store i64 undef, i64* %bsp.0
  %bsp.1 = getelementptr i64, i64* %bsp.0, i64 1
  %t.1 = load i64, i64* %bsp.1
  %t.2 = icmp slt i64 %t.0, %t.1
  %t.3 = zext i1 %t.2 to i64
  store i64 %t.3, i64* %bsp.1
  ret i64* %bsp.1
}

define private i64** @pop_a1(i64** %asp.0) #0 {
  store i64* undef, i64** %asp.0
  %asp.1 = getelementptr i64*, i64** %asp.0, i64 -1
  ret i64** %asp.1
}

define private i64* @pop_b1(i64* %bsp.0) #0 {
  store i64 undef, i64* %bsp.0
  %bsp.1 = getelementptr i64, i64* %bsp.0, i64 1
  ret i64* %bsp.1
}

define private i64* @print_int(i64* %bsp.0) #0 {
  %t.0 = load i64, i64* %bsp.0
  store i64 undef, i64* %bsp.0
  call i64 (i8*, ...) @printf(i8* getelementptr inbounds ([3 x i8], [3 x i8]* @printf_d, i64 0, i64 0), i64 %t.0)
  %bsp.1 = getelementptr i64, i64* %bsp.0, i64 1
  ret i64* %bsp.1
}

define private i64** @push_a(i64 %n, i64** %asp.0) #0 {
  %asp.1 = getelementptr i64*, i64** %asp.0, i64 %n
  %t.0 = load i64*, i64** %asp.1
  %asp.2 = getelementptr i64*, i64** %asp.0, i64 1
  store i64* %t.0, i64** %asp.2
  ret i64** %asp.2
}

define private i64* @push_b(i64 %n, i64* %bsp.0) #0 {
  %bsp.1 = getelementptr i64, i64* %bsp.0, i64 %n
  %t.0 = load i64, i64* %bsp.1
  %bsp.2 = getelementptr i64, i64* %bsp.0, i64 -1
  store i64 %t.0, i64* %bsp.2
  ret i64* %bsp.2
}

define private i64** @push_node(i64* %label, i64 %arity, i64** %asp.0) #0 {
entry:
  %n.0 = load i64*, i64** %asp.0
  %label.0 = ptrtoint i64* %label to i64
  store i64 %label.0, i64* %n.0
  br label %loop

loop:
  %asp.1 = phi i64** [%asp.0, %entry], [%asp.2, %loop.0]
  %arity.0 = phi i64 [%arity, %entry], [%arity.1, %loop.0]
  %t.0 = icmp eq i64 %arity.0, 0
  br i1 %t.0, label %done, label %loop.0
done:
  ret i64** %asp.1

loop.0:
  %n.1 = getelementptr i64, i64* %n.0, i64 %arity.0
  %n.2 = load i64, i64* %n.1
  %n.3 = inttoptr i64 %n.2 to i64*
  %asp.2 = getelementptr i64*, i64** %asp.1, i64 1
  store i64* %n.3, i64** %asp.2
  %arity.1 = sub i64 %arity.0, 1
  br label %loop
}

define private i64* @pushI(i64 %i, i64* %bsp.0) #0 {
  %bsp.1 = getelementptr i64, i64* %bsp.0, i64 -1
  store i64 %i, i64* %bsp.1
  ret i64* %bsp.1
}

define private i64* @pushI_a(i64 %n, i64* %bsp.0, i64** %asp.0) #0 {
  %asp.1 = getelementptr i64*, i64** %asp.0, i64 %n
  %n.0 = load i64*, i64** %asp.1
  %n.1 = getelementptr i64, i64* %n.0, i64 1
  %t.0 = load i64, i64* %n.1

  %bsp.1 = getelementptr i64, i64* %bsp.0, i64 -1
  store i64 %t.0, i64* %bsp.1
  ret i64* %bsp.1
}

define private i64* @subI(i64* %bsp.0) #0 {
  %t.0 = load i64, i64* %bsp.0
  store i64 undef, i64* %bsp.0
  %bsp.1 = getelementptr i64, i64* %bsp.0, i64 1
  %t.1 = load i64, i64* %bsp.1
  %t.2 = sub i64 %t.0, %t.1
  store i64 %t.2, i64* %bsp.1
  ret i64* %bsp.1
}

define private i64* @update_b(i64 %n1, i64 %n2, i64* %bsp.0) #0 {
  %bsp.1 = getelementptr i64, i64* %bsp.0, i64 %n1
  %t.0 = load i64, i64* %bsp.1
  %bsp.2 = getelementptr i64, i64* %bsp.0, i64 %n2
  store i64 %t.0, i64* %bsp.2
  ret i64* %bsp.0
}

define private i64* @updatepop_b01(i64* %bsp.0) #0 {
  %t.0 = load i64, i64* %bsp.0
  store i64 undef, i64* %bsp.0
  %bsp.1 = getelementptr i64, i64* %bsp.0, i64 1
  store i64 %t.0, i64* %bsp.1
  ret i64* %bsp.1
}

define private i64* @peek_a(i64** %asp) #0 {
  %t = load i64*, i64** %asp
  ret i64* %t
}

define private i64 @peek_b(i64* %bsp) #0 {
  %t = load i64, i64* %bsp
  ret i64 %t
}

@INT = constant {i64, i64, i64*, i64, i8, i8, i8}
  {i64 0, i64 0, i64* inttoptr (i64 0 to i64*), i64 3, i8 73, i8 78, i8 84}, align 8

define {i64*,i64**,i64*} @_cycle_in_spine(i64* %hp, i64** %globasp)
    align 8
    prefix {i8*, i64} {i8* inttoptr (i64 0 to i8*), i64 0} {
  call i64 (i8*, ...) @printf(i8* getelementptr inbounds ([16 x i8], [16 x i8]* @printf_cycle, i64 0, i64 0))
  unreachable
}