/**
Interactive Clean

Clean program to easily compile and run one-line Clean expressions

The MIT License (MIT)

Copyright (c) 2015 Camil Staps <info@camilstaps.nl>

Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the "Software"), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all
copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
SOFTWARE.
 */
module iclean

import StdEnv
import Data.Maybe

import ReadLine

import ExtraString

// SETTINGS
temp_path :== "/tmp/"
temp_module :== "iclean"
readline_history :== "/home/.iclean_history"
template :== map ((+++) "import ") ["StdEnv", "StdDynamic", "Gast.GenLibTest"]
template_file :== "/home/.iclean_template"
// END SETTINGS

temp_file =: temp_path +++ temp_module +++ ".icl"

help =:
	"\tInteractive Clean - known commands:\n\n" +++
	"\t:quit\t\t\tExit iClean\n" +++
	"\t:mem\t\t\tDisplay current memory\n" +++
	"\t:help\t\t\tDisplay this message\n\n" +++
	"\t:set K V\t\tSet iClean's setting K to value V\n\n" +++
	"\t:def F X1 .. Xn = RHS\tAdd a rewrite rule to the memory\n" +++
	"\t:undef F\t\tRemove all rewrite rules starting with 'F ' from the memory\n"

:: Status
	= { memory :: [String]
	  , settings :: Settings
	  }

instance zero Status where zero = { memory = [], settings = zero }

:: Settings
	= { show_type   :: Bool
	  , show_result :: Bool
	  }

instance zero Settings where zero = { show_type = False, show_result = True }

Start :: *World -> *World
Start w
# w = setReadLineName "iClean" w
# w = usingHistory w
# w = checkedWorldFunc readHistory "Couldn't read history" readline_history w
# (more_template,w) = readTemplate template_file w
# w = loop {zero & memory = template ++ more_template} True w
# w = checkedWorldFunc writeHistory "Couldn't write history" readline_history w
= w
where
	loop :: !Status Bool !*World -> *World
	loop stat success w
	# prompt                = color (if success None Red) "λ. "
	# (s,w)                 = readLine prompt False w
	| isNothing s           = print "\n" w
	# s                     = fromJust s
	| s == ""               = loop stat False (print "Use Ctrl-D to exit\n" w)
	# w                     = addHistory s w
	| s == ":quit" || s == ":q" = w
	| s == ":mem"           = loop stat True (print (join "\n" stat.memory) w)
	| matches ":def " s     = loop {stat & memory = stat.memory ++ [skip 5 s]} True w
	| matches ":undef " s   = loop {stat & memory = filter (undef (skip 7 s)) stat.memory} True w
	| matches ":set " s
		# (setting, value)  = span ((<>) ' ') (fromString (skip 5 s))
		# (setting, value)  = (toString setting, toString (drop 1 value))
		# (ok, msg, stat)       = set setting value stat
		= loop stat ok (if (isNothing msg) id (print (fromJust msg +++ "\n")) w)
	| s == ":help"          = loop stat True (print help w)
	| matches "import " s   = loop {stat & memory = stat.memory ++ [s]} True w
	| matches ":" s         = loop stat False (print ("Unknown command\n") w)
	# w                     = writemodule stat s w
	# (r,w)                 = compile temp_path temp_module w
	| r <> 0                = loop stat False w
	# (r,w)                 = run (temp_path +++ temp_module) w
	| r <> 0                = loop stat False w
	= loop stat True w

	undef :: !String !String -> Bool
	undef n h = not (matches (n +++ " ") h)

	readTemplate :: !String !*World -> *([String], *World)
	readTemplate f w
	# (ok,f,w)  = fopen f FReadText w
	| not ok    = ([], w)
	# (lines,f) = readLines f
	# (ok,w)    = fclose f w
	= (lines, w)
	where
		readLines :: !*File -> *([String], *File)
		readLines f
		# (end,f)   = fend f
		| end       = ([], f)
		# (line,f)  = freadline f
		# (lines,f) = readLines f
		= ([line % (0,size line - 2):lines], f)

// iClean functions
set :: !String !String !Status -> (Bool, Maybe String, Status)
set k v stat = case lookup k settings of
	Nothing  = (False, Just "Unknown setting", stat)
	(Just f) = f v stat
where
	set_bool :: String String (Bool -> Status -> Status) String Status -> (Bool, Maybe String, Status)
	set_bool iftrue iffalse f s stat
	| isMember s ["True",  "true",  "1"] = (True,  Just iftrue,  f True stat)
	| isMember s ["False", "false", "0"] = (False, Just iffalse, f False stat)
	= (False, Just ("Couldn't parse '" +++ v +++ "' as boolean"), stat)

	settings =
		[ ("show_type", set_bool "Showing types" "Not showing types"
			(\b s -> {s & settings.show_type = b}))
		, ("show_result", set_bool "Showing results" "Not showing results"
			(\b s -> {s & settings.show_result = b}))
		]

	lookup :: k [(k,v)] -> Maybe v | == k
	lookup _ [] = Nothing
	lookup k [(k`,v):vs] = if (k == k`) (Just v) (lookup k vs)

checkedWorldFunc :: (a *World -> (Bool, *World)) !String !a !*World -> *World
checkedWorldFunc f err s w
# (ok, w) = f s w
| not ok = print (err +++ "\n") w
| otherwise = w

print :: String *World -> *World
print s w
# (io,w) = stdio w
# io = fwrites s io
# (ok,w) = fclose io w
| not ok = abort "Couldn't close stdio\n"
| otherwise = w

writemodule :: !Status !String !*World -> *World
writemodule stat s w
# (ok,f,w) = fopen temp_file FWriteText w
| not ok = abort ("Couldn't open " +++ temp_file +++ " for writing.\n")
# f = f <<< "module " <<< temp_module <<< "\n"
# f = f <<< join "\n" stat.memory
# f = f <<< "start = " <<< s <<< "\n"
		<<< "Start = " <<< start
# (ok,w) = fclose f w
| not ok = abort ("Couldn't close " +++ temp_file +++ "\n")
| otherwise = w
where
	start = case (stat.settings.show_type, stat.settings.show_result) of
		(True,  True)  = type +++ "+++\" :: \"+++" +++ rslt +++ "+++\"\\n\"\n"
		(True,  False) = type +++ "+++\"\\n\"\n"
		(False, True)  = rslt +++ "+++\"\\n\"\n"
		(False, False) = "()"
	where
		type = "toString (typeCodeOfDynamic (dynamic start))"
		rslt = "foldl (+++) \"\" (genShow{|*|} \"\" True start [])"

// C functions
compile :: !String !String !*World -> *(!Int,!*World)
compile _ _ _ = code {
	ccall compile "SS:p:A"
}

run :: !String !*World -> (!Int, !*World)
run _ _ = code {
	ccall run "S:I:A"
}