/**
 * Interactive Clean
 *
 * Clean program to easily compile and run one-line Clean expressions
 *
 * The MIT License (MIT)
 * 
 * Copyright (c) 2015 Camil Staps <info@camilstaps.nl>
 * 
 * Permission is hereby granted, free of charge, to any person obtaining a copy
 * of this software and associated documentation files (the "Software"), to deal
 * in the Software without restriction, including without limitation the rights
 * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 * copies of the Software, and to permit persons to whom the Software is
 * furnished to do so, subject to the following conditions:
 * 
 * The above copyright notice and this permission notice shall be included in all
 * copies or substantial portions of the Software.
 * 
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
 * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
 * SOFTWARE.
 */
module iclean

import StdEnv

// SETTINGS
temp_path :== "/tmp/"
temp_module :== "iclean"
// END SETTINGS

temp_file :== temp_path +++ temp_module +++ ".icl"

Start :: *World -> *World
Start w
# w = loop w
= w
where
    loop :: *World -> *World
    loop w
    #! w = print "> " w
    #! (s,w) = readline w
    | s == "" = w
    #! w = writemodule s w
    #! w = compile temp_path temp_module w
    #! w = run (temp_path +++ temp_module) w
    = loop w

print :: String *World -> *World
print s w
# (io,w) = stdio w
# io = fwrites s io
# (ok,w) = fclose io w
| not ok = abort "Couldn't close stdio\n"
| otherwise = w

readline :: *World -> *(String,*World)
readline w
# (io,w) = stdio w
# (s,io) = freadline io
# (ok,w) = fclose io w
| not ok = abort "Couldn't close stdio\n"
| otherwise = (s % (0,length (l s) - 2), w)
where
    l :: String -> [Char]
    l s = fromString s

writemodule :: String *World -> *World
writemodule s w
# (ok,f,w) = fopen temp_file FWriteText w
| not ok = abort ("Couldn't open " +++ temp_file +++ " for writing.\n")
# f = fwrites ("module " +++ temp_module +++ "\n") f
# f = fwrites "import StdEnv\n" f
# f = fwrites ("Start = " +++ s +++ "\n") f
# (ok,w) = fclose f w
| not ok = abort ("Couldn't close " +++ temp_file +++ "\n")
| otherwise = w

compile :: !String !String *World -> *World
compile _ _ _ = code {
    ccall compile "SS:V:p"
}

run :: !String *World -> *World
run _ _ = code {
    ccall run "S:V:p"
}