/**
Interactive Clean

Clean program to easily compile and run one-line Clean expressions

The MIT License (MIT)

Copyright (c) 2015 Camil Staps <info@camilstaps.nl>

Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the "Software"), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all
copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
SOFTWARE.
 */
module iclean

import StdEnv
import ReadLine
import ExtraString

// SETTINGS
temp_path :== "/tmp/"
temp_module :== "iclean"
readline_history :== "/home/.iclean_history"
template :== map ((+++) "import ") ["StdEnv", "StdDynamic", "genLibTest"]
template_file :== "/home/.iclean_template"
// END SETTINGS

temp_file :== temp_path +++ temp_module +++ ".icl"

help :==
	"\tInteractive Clean - known commands:\n\n" +++
	"\t:quit\t\t\tExit iClean\n" +++
	"\t:mem\t\t\tDisplay current memory\n" +++
	"\t:help\t\t\tDisplay this message\n\n" +++
	"\t:import MODULE\t\tAdd an import to the memory\n" +++
	"\t:def F X1 .. X2 = RHS\tAdd a rewrite rule to the memory\n" +++
	"\t:undef F\t\tRemove all rewrite rules starting with 'F ' from the memory\n"

Start :: *World -> *World
Start w
# w = setReadLineName "iClean" w
# w = usingHistory w
# w = checkedWorldFunc readHistory "Couldn't read history" readline_history w
# (more_template,w) = readTemplate template_file w
# w = loop (template ++ more_template) True w
# w = checkedWorldFunc writeHistory "Couldn't write history" readline_history w
= w
where
	loop :: ![String] Bool !*World -> *World
	loop mem success w
	# prompt                = color (if success None Red) "λ. "
	# (s,w)                 = readLine prompt False w
	| isNothing s           = print "\n" w
	# s                     = fromJust s
	| s == ""               = loop mem False (print "Use Ctrl-D to exit\n" w)
	# w                     = addHistory s w
	| s == ":quit" || s == ":q" = w
	| s == ":mem"           = loop mem True (print (join "\n" mem) w)
	| matches ":import " s  = loop (mem ++ [skip 1 s]) True w
	| matches ":def " s     = loop (mem ++ [skip 5 s]) True w
	| matches ":undef " s   = loop (filter (undef (skip 7 s)) mem) True w
	| s == ":help"          = loop mem True (print help w)
	| matches ":" s         = loop mem False (print ("Unknown command\n") w)
	# w                     = writemodule mem s w
	# (r,w)                 = compile temp_path temp_module w
	| r <> 0                = loop mem False w
	# (r,w)                 = run (temp_path +++ temp_module) w
	| r <> 0                = loop mem False w
	= loop mem True w

	undef :: !String !String -> Bool
	undef n h = not (matches (n +++ " ") h)

	readTemplate :: !String !*World -> *([String], *World)
	readTemplate f w
	# (ok,f,w)  = fopen f FReadText w
	| not ok    = ([], w)
	# (lines,f) = readLines f
	# (ok,w)    = fclose f w
	= (lines, w)
	where
		readLines :: !*File -> *([String], *File)
		readLines f
		# (end,f)   = fend f
		| end       = ([], f)
		# (line,f)  = freadline f
		# (lines,f) = readLines f
		= ([line % (0,size line - 2):lines], f)

// iClean functions
checkedWorldFunc :: (a *World -> (Bool, *World)) !String !a !*World -> *World
checkedWorldFunc f err s w
# (ok, w) = f s w
| not ok = print (err +++ "\n") w
| otherwise = w

print :: String *World -> *World
print s w
# (io,w) = stdio w
# io = fwrites s io
# (ok,w) = fclose io w
| not ok = abort "Couldn't close stdio\n"
| otherwise = w

writemodule :: ![String] !String !*World -> *World
writemodule mem s w
# (ok,f,w) = fopen temp_file FWriteText w
| not ok = abort ("Couldn't open " +++ temp_file +++ " for writing.\n")
# f = f <<< "module " <<< temp_module <<< "\n"
# f = f <<< join "\n" mem
# f = f <<< "start = " <<< s <<< "\n"
        <<< "rslt = genShow{|*|} \"\" True start []\n"
        <<< "Start = toString (typeCodeOfDynamic (dynamic start)) "
        <<< "+++ \" :: \" +++ foldl (+++) \"\" rslt +++ \"\\n\"\n"
# (ok,w) = fclose f w
| not ok = abort ("Couldn't close " +++ temp_file +++ "\n")
| otherwise = w

// C functions
compile :: !String !String !*World -> *(!Int,!*World)
compile _ _ _ = code {
	ccall compile "SS:p:A"
}

run :: !String !*World -> (!Int, !*World)
run _ _ = code {
	ccall run "S:I:A"
}