implementation module Gtk.Widgets.Sheet.Signal

import StdEnv
import StdMaybe

import Control.Monad
import Data.Functor
import System._Pointer

import Gtk

instance signalHandler GtkSheetSignalHandler
where
	signalName handler = case handler of
		EnterPressedHandler _ -> "enter-pressed"
		TraverseHandler _     -> "traverse"
	signalHandler handler = case handler of
		EnterPressedHandler f -> SHI_Pointer_Bool \_ -> not <$> f
		TraverseHandler f -> SHI_Int_Int_Pointer_Pointer_Bool \oldrow oldcol newrowp newcolp ->
			let newrow = readInt4S newrowp 0; newcol = readInt4S newcolp 0 in
			// NB, possible bug in GtkSheet: when a cell is selected and the
			// user then presses enter, this emits a traverse signal with new
			// location (-1,0), and selects the entire first column. This seems
			// undesirable, so we prevent it.
			if (newrow < 0 || newcol < 0)
				(pure False)
				(f (if (oldrow<0) Nothing (Just (oldrow,oldcol))) (newrow,newcol) >>= \r -> case r of
					Nothing ->
						pure False
					Just (row,col) ->
						appWorld (forceEval (writeInt4 newrowp 0 row)) >>|
						appWorld (forceEval (writeInt4 newcolp 0 col)) >>|
						pure True)