###
Web Frontend for Botleagues
Copyright (C) 2015 Camil Staps <info@camilstaps.nl>

This program is free software: you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation, either version 3 of the License, or
(at your option) any later version.

This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
GNU General Public License for more details.

You should have received a copy of the GNU General Public License
along with this program.  If not, see <http://www.gnu.org/licenses/>.
###

@BotleaguesCallback =

    common: (data) ->
        console.log data

    register: (data) ->
        BotleaguesCallback.common data

        $ 'form.form-register .form-group'
            .removeClass 'has-feedback has-success has-warning has-error'
            .find '.form-control-feedback, .feedback'
            .remove()

        if data.error?
            BotleaguesFrontend.error
                message: data.error
                prepend_to: $ 'form.form-register'

            for key, msgs of data.errors
                error_msg = msgs.join '; '

                $('#register-' + key)
                    .attr 'title', error_msg
                    .parent()
                    .addClass 'has-feedback has-error'
                    .append(
                        $ '<span>'
                            .addClass 'glyphicon glyphicon-remove form-control-feedback'
                            .attr 'aria-hidden', true
                    )
                    .find 'label'
                    .append(
                        $ '<span>'
                            .addClass 'feedback pull-right text-danger'
                            .text error_msg
                    )

        else if data.user?
            BotleaguesFrontend.success
                message: 'Your account has been created'
                prepend_to: $ 'form.form-register'

            $ 'form.form-register input'
                .val ''

        else
            BotleaguesFrontend.error
                message: 'Unknown error'
                prepend_to: $ 'form.form-register'

        return

    login: (data) ->
        BotleaguesCallback.common data

        if data.user_token?
            BotleaguesFrontend.success
                message: 'Login successful! Refreshing the page...'

            $.cookie Botleagues.cookie_login_email, data.user_token.userEmail
            $.cookie Botleagues.cookie_login_token, data.user_token.token
            $.cookie Botleagues.cookie_login_valid_till, (new Date()).getTime() + Date.parse(data.user_token.valid_till) - Date.parse(data.user_token.updated_at)

            window.setTimeout (-> window.location = 'profile'), 1000

        else
            BotleaguesFrontend.error
                message: if data.error? then data.error else "Could not login."

            $.removeCookie Botleagues.cookie_login_email

        return